Вывод ноты BEEP 1,0 с цветными полосками на рамке

God Mode:

Debugger				; Открыть отладчик для ввода данных
Dec					; Переключить отображение чисел в десятичный режим
Go To 23613				; Переместиться по памяти на нужный адрес
23613 <-- 65364				; Установить накладку на вершину SP-столбика для корректного возврата в BASIC

SP <-- 65364
PC <-- 40000				; Установить Стрелочку на запускаемую подпрограмму

Go To 40000				; Переместиться по памяти на нужный адрес
40000 <-- 33 106 6 17 5 1 243 125 203 61 203 61
40012 <-- 47 230 3 079 6 0 221 33 90 156 221 9
40024 <-- 62 4 0 0 0 4 12 13 32 253 14 63 5
40037 <-- 194 95 156 238 18 211 254 68 79 203 103
40048 <-- 32 9 122 179 40 9 121 77 27 221 233 77
40060 <-- 12 221 233 251 58 72 92 230 56 15 15 15
40072 <-- 246 8 211 254 195 162 18
Trace					; Выйти из отладчика и запустить программу

Ассемблер EmuZWin:

	ORG  40000

	LD HL, 1642		; Длина звука
	LD DE, 261		; Тональность
beeper:	DI
	LD   A, L
	SRL  L
	SRL  L
	CPL
	AND  3
	LD   C, A
	LD   B, 0
	LD   IX, BEIX3
	ADD  IX, BC
	LD   A, 4		; Цвет первой полосы во время звучания (0...7)
BEIX3:	NOP
BEIX2:	NOP
BEIX1:	NOP
BEIX0:	INC  B
	INC  C
BEHLLP:	DEC  C
	JR   NZ, BEHLLP
	LD   C, 63   
	DEC  B
	JP   NZ, BEHLLP
	XOR  18			; Шаг чередования цвета для 2-й полоски (16...23)
	OUT  (254), A
	LD   B, H
	LD   C, A
	BIT  4, A
	JR   NZ, BEAGAIN
	LD   A, D     
	OR   E      
	JR   Z, BEEND
	LD   A, C
	LD   C, L
	DEC  DE
	JP   (IX)
BEAGAIN:LD   C, L
	INC  C
	JP   (IX)
BEEND:	EI
	LD   A, (23624)		; Восстановление исходного цвета рамки
	AND  56
	RRCA
	RRCA
	RRCA
	OR   8
	OUT  (254), A
	RET			; Выход в BASIC
